比如，我们想直观地看孕期吸烟者者和非吸烟者两组新生儿的出生体重是否有差异，可以通过Stata社区命令betterbar实现。

Stata命令如下：

/*读取演示数据*/
webuse lbw
/*绘制误差条形图，用前需先安装，如ssc install betterbar，详见文末*/
betterbar bwt, over(smoke) ci

上图是最基本的，默认是水平条形图（horizontal bar），我们可以转成垂直条形图（vertical bar），并进一步调整，Stata命令如下：

/*条形图添加标签（均值），垂直条形图，图例加样本量，标签保留1位小数*/
betterbar bwt, over(smoke) barlab vertical n ci format(%9.1f)

不同的条形图还可以自定义颜色，比如吸烟组为红色，非吸烟组为绿色，Stata命令如下：

/*颜色顺序是从右向左，从下向上*/
betterbar bwt, over(smoke) barlab vertical n ci format(%9.1f) ///
barcolor(red green)

基本上误差条形图就算绘制完成了，当然还有一些通用的图形调整。

如你可能嫌弃图例有边框，且背景是白色太扎眼，Stata命令如下：

/*去掉图例边框，将背景色去掉*/
betterbar bwt, over(smoke) barlab vertical n ci format(%9.1f) ///
barcolor(red green) legend(region(lstyle(none) fcolor(none)))  

如果需要黑白图形，还可以再调整，Stata命令如下：

/*取掉网格线，整图背景为白色，图形为单色（内容区背景为白）*/
betterbar bwt, over(smoke) barlab vertical n ci  format(%9.1f) ///
barcolor(red green) legend( region(lstyle(none) fcolor(none)))  ///
ylabel(,nogrid) graphregion(color(white))  scheme(s2mono) 

命令说明
该命令为Stata社区命令，由美国乔治敦大学（Georgetown University）的研究员Benjamin Daniels开发，邮箱：[email protected]，[email protected]。

通过SSC命令安装：

/*因网络问题（DNS解析），很可能会连接失败*/
ssc install betterbar, replace

或者通过GitHub安装：

/*因网络问题（DNS解析），很可能会连接失败*/
net from https://github.com/bbdaniels/stata/raw/main/
net describe betterbar
net install betterbar,replace

或者直接下载程序文件：
访问 https://github.com/bbdaniels/betterbar
点击 Code→Download ZIP 下载并解压
选择 四个文件：betterbar.ado、betterbar.sthlp、betterbarci.ado、betterbarci.sthlp
移至 PLUS目录，首字母为b的文件夹下
/*该位置不同电脑不一样，可以用Stata命令 sysdir 查看*/

sysdir

之后输入帮助命令查看，若能看到帮助文件，说明安装成功！

/*命令为 help + 程序名称*/
help betterbar

完，本文内容交流请移步：