webuse grunfeld, clear

因为数据需要生成，生成时会覆盖原有数据，为此我们新建一个临时数据框，Stata代码如下：

/*创建临时数据框并复制数据*/
frame copy default lian_g
/*生成需要的数据并存至临时数据框*/
frame lian_g:statsby mean=r(mean) sd=r(sd) size=r(N), by(year):summarize invest

然后就可以基于临时数据框的数据绘图了，Stata代码如下（注意所有的命令都加上了临时数据框的前缀）：

/*绘图命令*/
frame lian_g:serrbar mean sd year,ytitle(Invest)
/*绘图命令，x轴刻度设置自定义，灵活性更高*/
frame lian_g:serrbar mean sd year,ytitle(Invest) xlabel(1935(5)1955) xtick(1935(1)1955) 
/*绘图命令，x轴刻度设置自定义，普适性更强*/
frame lian_g:serrbar mean sd year,ytitle(Invest) xtick(#5) xmticks(##5) 
/*绘图命令，x轴刻度设置自定义，可混合使用*/
frame lian_g:serrbar mean sd year,ytitle(Invest) xlabel(1935(5)1955) xmticks(##5)
/*绘图结束，删除临时数据框*/
frame drop lian_g

注意，也可以不加数据框前缀。上面的命令因为我们在默认的数据框内执行命令所以需要加临时数据框前缀，如果我们将当前的数据框从默认数据框切换到临时数据框，就可以不加数据框前缀了。

/*重新从头运行一次，注意区别*/
webuse grunfeld, clear
/*当前的数据框切换到临时数据框*/
frame copy default lian_g
frame change lian_g
statsby mean=r(mean) sd=r(sd) size=r(N), by(year):summarize invest
serrbar mean sd year,ytitle(Invest) xtick(#5) xmticks(##5) 
/*当前的数据框切换回默认数据框*/
frame change default
frame drop lian_g